フルスクラッチとは言わないが、抽象化ライブラリを使わず、マイコンの制御レジスタを番地指定で設定して動かしてみる。先人のサンプルをベースに、BluePill(STM32F103C8)でLチカさせてみた。
BulePillのLEDはPC13（GPIO_Cの13）に接続されているので、GPIO_Cの13をL/HさせることでLチカが可能になる。
制御レジスタを番地指定で直接叩いてLEDをチカチカさせるサンプル。STM32のクロック制御部等は全く変更しておらず、デフォルト設定で動いています。クロックについては何がどうなっているのか(クロックはどこから供給されているのか、何MHzなのか、PLLで逓倍？しているのか、してないのか、etc)全く理解していません。
/*
* LED Blink Test for the STM32F103C8
*
* original source : Author : Chuck McManis
* http://robotics.mcmanis.com/src/arm-blink/blink-example.html
*
*/
#include <stdint.h>
#define GPIOC 0x40011000ul
#define GPIOC_CRL (*(uint32_t *)(GPIOC+0x00ul))
#define GPIOC_CRH (*(uint32_t *)(GPIOC+0x04ul))
#define GPIOC_IDR (*(uint32_t *)(GPIOC+0x08ul))
#define GPIOC_ODR (*(uint32_t *)(GPIOC+0x0cul))
#define GPIOC_BSRR (*(uint32_t *)(GPIOC+0x10ul))
#define GPIOC_BRR (*(uint32_t *)(GPIOC+0x14ul))
#define GPIOC_LCKR (*(uint32_t *)(GPIOC+0x14ul))
#define RCC_BASE 0x40021000ul
#define RCC_APB2ENR (*(uint32_t *)(RCC_BASE + 0x18ul))
#define GPIOC_ENA 0x01 << 4 // C:bit4
#define GPIOC_13 13
#define GPIOC_8 8
#define OUT10MH 0x01
#define CNF13_GENPP 0x00000000ul
#define MODE13_OUT10MH OUT10MH << ((GPIOC_13 - GPIOC_8) *4)
#define DELAY_TIME 300000
void wait(int delay_time);
// No exit, just sit and wait
void _exit(int r) {
while (1) {
asm("nop");
}
}
void main() {
// setup GPIOC PORT
RCC_APB2ENR = GPIOC_ENA; // Enable clocks to GPIOC
GPIOC_CRH = CNF13_GENPP | MODE13_OUT10MH; // set GPIOC_13 as OUTPUT
GPIOC_BSRR = 1 << GPIOC_13 ; //LED off
while (1) {
GPIOC_BRR = 1 << GPIOC_13; // LED on
wait(DELAY_TIME);
GPIOC_BSRR = 1 << GPIOC_13 ; //LED off
wait(DELAY_TIME);
}
}
void wait(int delay_time){
unsigned int i = delay_time;
while(i--){
asm("nop");
}
}
void SystemInit() {
main();
}■追記
Cで書いたメインルーチンはまぁわかるとして、、ビルドする際にリンカーの動作を決めるlinker scriptがワケ分からない。以下はLチカ用バイナリをビルドするときに使っているlinker script。原作者のChuck McManis氏のをベースに、STM32F103C8に合うようにLENGTHだけ変えて使ってる。なんとなくわかる所もあるけど、こんなに全部の記述は不要と思うのだが、どれを削っていいのかも分からない。
linker script自体はメモリ配置（厳密にはサイズか）ぐらいしか変更しないとはいえ、まったくのBlackBoxというのもどうかと思われ、最低限は理解したい。Linker Scriptの解説記事をメモ
GNU Cを使いこなそう | 株式会社コンピューテックス
/* Linker script to configure memory regions.
* Need modifying for a specific board.
* FLASH.ORIGIN: starting address of flash
* FLASH.LENGTH: length of flash
* RAM.ORIGIN: starting address of RAM bank 0
* RAM.LENGTH: length of RAM bank 0
*/
MEMORY
{
FLASH (rx) : ORIGIN = 0x08000000, LENGTH = 64K /* 64K */
RAM (rwx) : ORIGIN = 0x20000000, LENGTH = 20K /* 20K */
}
/* Linker script to place sections and symbol values. Should be used together
* with other linker script that defines memory regions FLASH and RAM.
* It references following symbols, which must be defined in code:
* Reset_Handler : Entry of reset handler
*
* It defines following symbols, which code can use without definition:
* __exidx_start
* __exidx_end
* __copy_table_start__
* __copy_table_end__
* __zero_table_start__
* __zero_table_end__
* __etext
* __data_start__
* __preinit_array_start
* __preinit_array_end
* __init_array_start
* __init_array_end
* __fini_array_start
* __fini_array_end
* __data_end__
* __bss_start__
* __bss_end__
* __end__
* end
* __HeapLimit
* __StackLimit
* __StackTop
* __stack
*/
ENTRY(Reset_Handler)
SECTIONS
{
.text :
{
KEEP(*(.isr_vector))
*(.text*)
KEEP(*(.init))
KEEP(*(.fini))
/* .ctors */
*crtbegin.o(.ctors)
*crtbegin?.o(.ctors)
*(EXCLUDE_FILE(*crtend?.o *crtend.o) .ctors)
*(SORT(.ctors.*))
*(.ctors)
/* .dtors */
*crtbegin.o(.dtors)
*crtbegin?.o(.dtors)
*(EXCLUDE_FILE(*crtend?.o *crtend.o) .dtors)
*(SORT(.dtors.*))
*(.dtors)
*(.rodata*)
KEEP(*(.eh_frame*))
} > FLASH
.ARM.extab :
{
*(.ARM.extab* .gnu.linkonce.armextab.*)
} > FLASH
__exidx_start = .;
.ARM.exidx :
{
*(.ARM.exidx* .gnu.linkonce.armexidx.*)
} > FLASH
__exidx_end = .;
/* To copy multiple ROM to RAM sections,
* uncomment .copy.table section and,
* define __STARTUP_COPY_MULTIPLE in startup_ARMCMx.S */
.copy.table :
{
. = ALIGN(4);
__copy_table_start__ = .;
LONG (__etext)
LONG (__data_start__)
LONG (__data_end__ - __data_start__)
__copy_table_end__ = .;
} > FLASH
/* To clear multiple BSS sections,
* uncomment .zero.table section and,
* define __STARTUP_CLEAR_BSS_MULTIPLE in startup_ARMCMx.S */
.zero.table :
{
. = ALIGN(4);
__zero_table_start__ = .;
LONG (__bss_start__)
LONG (__bss_end__ - __bss_start__)
__zero_table_end__ = .;
} > FLASH
__etext = .;
.data : AT (__etext)
{
__data_start__ = .;
*(vtable)
*(.data*)
. = ALIGN(4);
/* preinit data */
PROVIDE_HIDDEN (__preinit_array_start = .);
KEEP(*(.preinit_array))
PROVIDE_HIDDEN (__preinit_array_end = .);
. = ALIGN(4);
/* init data */
PROVIDE_HIDDEN (__init_array_start = .);
KEEP(*(SORT(.init_array.*)))
KEEP(*(.init_array))
PROVIDE_HIDDEN (__init_array_end = .);
. = ALIGN(4);
/* finit data */
PROVIDE_HIDDEN (__fini_array_start = .);
KEEP(*(SORT(.fini_array.*)))
KEEP(*(.fini_array))
PROVIDE_HIDDEN (__fini_array_end = .);
KEEP(*(.jcr*))
. = ALIGN(4);
/* All data end */
__data_end__ = .;
} > RAM
.bss :
{
. = ALIGN(4);
__bss_start__ = .;
*(.bss*)
*(COMMON)
. = ALIGN(4);
__bss_end__ = .;
} > RAM
.heap (COPY):
{
__end__ = .;
PROVIDE(end = .);
*(.heap*)
__HeapLimit = .;
} > RAM
/* .stack_dummy section doesn't contains any symbols. It is only
* used for linker to calculate size of stack sections, and assign
* values to stack symbols later */
.stack_dummy (COPY):
{
*(.stack*)
} > RAM
/* Set stack top to end of RAM, and stack limit move down by
* size of stack_dummy section */
__StackTop = ORIGIN(RAM) + LENGTH(RAM);
__StackLimit = __StackTop - SIZEOF(.stack_dummy);
PROVIDE(__stack = __StackTop);
/* Check if data + heap + stack exceeds RAM limit */
ASSERT(__StackLimit >= __HeapLimit, "region RAM overflowed with stack")
}■参考URL
ARM Cortex M4 Blink Example -- Chuck's Robotics Notebook
libopencm3: STM32F1
